Digging in windows10 mine

Published on by Yousfi Benameur

 

*1*created on 26 of october 2017
*!*	This is a personal platform to run all windows Apps,special folders,...
*!*	the method is to gather in a cursor a summary description and the command to run the application.
*!*	there is 282 applications indexed alphabetically.
*!*	there is 2 simple button to search any word in the list (first (green) to type the word),second  to continue searching (red).

*!*	Warning: depending on the windows version application can be run fine or fails(dont exist)
*!*	2 Another buttons:
*!*	     -first named "winApps" fire the special folder Window Applications (click to run).
*!*	     -Second names Windos CPLs gather all Control panel applications (applets) and can run them (click selected  in combo)

*!*	can build a project , add a simple config.fpw and compile an exe and use it as under hand utility tool.	


If !_vfp.StartMode=0
	On Shutdown Quit
Endi

Publi yform
yform=Newobject("yWinsApps0")
yform.Show
Read Events
Retu
*
Define Class ywinsApps0 As Form
	BorderStyle = 0
	Top = 0
	Left = 0
	Height = 434+30
	Width = 657
	ShowWindow = 2
	ShowTips = .T.
	Caption = ""
	MaxButton = .F.
	WindowState = 0
	alwaysonBottom=.t.
	xs = .F.

	Add Object grid1 As Grid With ;
		Anchor = 0, ;
		Height = 385, ;
		Left = 3, ;
		ReadOnly = .T., ;
		Top = 5, ;
		Width = 651, ;
		Name = "Grid1"

	Add Object label1 As Label With ;
		FontSize = 10, ;
		WordWrap = .T., ;
		Alignment = 2, ;
		BackStyle = 0, ;
		Caption = "", ;
		Height = 37, ;
		Left = 48, ;
		Top = 395, ;
		Width = 553, ;
		ForeColor = Rgb(255,0,0), ;
		Name = "Label1"

	Add Object command1 As CommandButton With ;
		AutoSize = .T., ;
		Top = 396, ;
		Left = 0, ;
		Height = 27, ;
		Width = 49, ;
		FontBold = .T., ;
		Caption = "WinApps", ;
		MousePointer = 15, ;
		BackColor = Rgb(128,255,0), ;
		Name = "Command1"

	Add Object shape1 As Shape With ;
		Top = 408, ;
		Left = 634, ;
		Height = 15, ;
		Width = 15, ;
		Curvature = 99, ;
		MousePointer = 15, ;
		ToolTipText = "Repeat", ;
		BackColor = Rgb(0,255,0), ;
		Name = "Shape1"

	Add Object shape2 As Shape With ;
		Top = 408, ;
		Left = 611, ;
		Height = 15, ;
		Width = 15, ;
		Curvature = 99, ;
		MousePointer = 15, ;
		ToolTipText = "sEARCH FOR A STRING", ;
		BackColor = Rgb(255,0,0), ;
		Name = "Shape2"

	Add Object IMAGE1  As Image With ;
		Picture = Home(1)+"graphics\bitmaps\offctlbr\small\color\help.bmp",;
		Height = 15,;
		Left = 592,;
		MousePointer = 15,;
		Top = 405,;
		Width = 16,;
		Name = "Image1"
  Add Object combo1 As ComboBox With ;
		Height = 37, ;
		Left = 80, ;
		Top = 420, ;
		Width = 168, ;
		Name = "Combo1"

	Add Object label2 As Label With ;
		AutoSize = .T., ;
		FontBold = .T., ;
		BackStyle = 0, ;
		Caption = "Applets CPL", ;
		Height = 17, ;
		Left = 5, ;
		Top = 424, ;
		Width = 71, ;
		ForeColor = Rgb(128,0,255), ;
		Name = "Label2"
		
   Procedure combo1.Init
		Local gnbre
		gnbre=Adir(gabase,"c:\windows\system32\*.cpl")
		With This
			.RowSourceType=0
			For i=1 To gnbre
				.AddItem(gabase(i,1))
			Endfor
			.ListIndex=1
			.Style=2
			.MousePointer=15
		Endwith
	Endproc

	Procedure combo1.Click
		Local m.result
		m.result =shellexecute(0,"open","c:\windows\system32\control.exe",Allt(This.Value),"c:\windows\system32\",1)
	Endproc

	Procedure my
		Lparameters nButton, nShift, nXCoord, nYCoord
		Sele ycurs
		Try
			Local m.x
			m.x=Allt(xcommand)
			*messagebox(m.x)
			Thisform.label1.Caption=Allt(xApplication)+":"+Allt(xcommand)
			Local m.result
			if lower(justext(m.x))=="cpl"
			m.x="inetcpl.cpl"
            m.result = ShellExecute(0, "open", "control.exe",m.x,"",1)
			else
			m.result = ShellExecute(0, "open", m.x,"","",1)
            endi
			If result<=32
				Messagebox("Fail to run!",16+4096,'',1200)
			Endi
		Catch
			Messagebox("An error was occured!",16+4096,"Error",1200)
		Endtry
	Endproc

	Procedure IMAGE1.Click
		Local m.myvar
		TEXT to m.myvar pretext 7 noshow
This is a personal platform to run all windows Apps,special folders,...
the method is to gather in a cursor a summary description and the command to run the application.
there is 282 applications indexed alphabetically.
there is 2 simple button to search any word in the list (first (green) to type the word),second  to continue searching (red).

Warning: depending on the windows version application can be run fine or fails(dont exist)
2 Another buttons:
     -first named "winApps" fire the special folder Window Applications (click to run).
     -Second names Windows CPLs gather all Control panel applications (applets) and can run them (click selected  in combo)

can build a project , add a simple config.fpw and compile n exe and use is as under hand utility tool.	
		ENDTEXT
		*messagebox(m.myvar,0+32+4096,"Cortana")
		Local oshell
		oshell = Createobject('WScript.Shell')
		oshell.Popup(m.myvar,0, 'Summary help', 0+32+4096)  &&4,16,48,64...
		oshell=Null
	Endproc

	Procedure Load
		&&shellexecute
		Declare Integer ShellExecute In SHELL32.Dll Integer nWinHandle,;
			STRING cOperation,;
			STRING cFileName,;
			STRING cParameters,;
			STRING cDirectory,;
			INTEGER nShowWindow

		Close Data All

		Set Memowidth To 8192
		Local m.myvar
		TEXT to m.myvar noshow
		3D Objects,shell:3D Objects
		About Windows dialog 	,winver
		Account Pictures,shell:AccountPictures
		Add Hardware Wizard 	,hdwwiz
		AddNewProgramsFolder,shell:AddNewProgramsFolder
		Adding a new Device 	,devicepairingwizard
		Administrative Tools,shell:Administrative Tools
		Advanced User Accounts 	,netplwiz
		Advanced User Accounts 	,azman.msc
		AppData,shell:AppData
		AppUpdatesFolder,shell:AppUpdatesFolder
		Application Shortcuts,shell:Application Shortcuts
		AppsFolder,shell:AppsFolder
		Backup and Restore 	,sdclt
		Bluetooth File Transfer 	,fsquirt
		CD Burning,shell:CD Burning
		CSCFolder,shell:CSCFolder
		Cache,shell:Cache
		Calculator 	,calc
		Camera Roll,shell:Camera Roll
		CameraRollLibrary,shell:CameraRollLibrary
		Certificates 	,certmgr.msc
		Change Computer Performance Settings 	,systempropertiesperformance
		Change Data Execution Prevention Settings 	,systempropertiesdataexecutionprevention
		Change Data Execution Prevention Settings 	,printui
		ChangeRemoveProgramsFolder,shell:ChangeRemoveProgramsFolder
		Character Map 	,charmap
		ClearType Tuner 	,cttune
		Color Management 	,colorcpl
		Command Prompt 	,cmd
		Common Administrative Tools,shell:Common Administrative Tools
		Common AppData,shell:Common AppData
		Common Desktop,shell:Common Desktop
		Common Documents,shell:Common Documents
		Common Programs,shell:Common Programs
		Common Start Menu,shell:Common Start Menu
		Common Start Menu Places,shell:Common Start Menu Places
		Common Startup,shell:Common Startup
		Common Templates,shell:Common Templates
		CommonDownloads,shell:CommonDownloads
		CommonMusic,shell:CommonMusic
		CommonPictures,shell:CommonPictures
		CommonRingtones,shell:CommonRingtones
		CommonVideo,shell:CommonVideo
		Component Services 	,comexp.msc
		Component Services 	,dcomcnfg
		Computer Management 	,compmgmt.msc
		Computer Management 	,compmgmtlauncher
		ConflictFolder,shell:ConflictFolder
		Connect to a Projector 	,displayswitch
		ConnectionsFolder,shell:ConnectionsFolder
		Contacts,shell:Contacts
		Control Panel 	,control
		ControlPanelFolder,shell:ControlPanelFolder
		Cookies,shell:Cookies
		Create A Shared Folder Wizard 	,shrpubw
		Create a System Repair Disc 	,recdisc
		CredentialManager,shell:CredentialManager
		CryptoKeys,shell:CryptoKeys
		DPAPI Key Migration Wizard 	,dpapimig
		Data Execution Prevention 	,systempropertiesdataexecutionprevention
		Date and Time 	,timedate.cpl
		Default Location 	,locationnotifications
		Desktop,shell:Desktop
		Development Files,shell:Development Files
		Device Manager 	,devmgmt.msc
		Device Manager 	,hdwwiz.cpl
		Device Metadata Store,shell:Device Metadata Store
		Device Pairing Wizard 	,devicepairingwizard
		Diagnostics Troubleshooting Wizard 	,msdt
		Digitizer Calibration Tool 	,tabcal
		DirectX Diagnostic Tool 	,dxdiag
		Disk Cleanup 	,cleanmgr
		Disk Defragmenter 	,dfrgui
		Disk Management 	,diskmgmt.msc
		Display 	,dpiscaling
		Display Color Calibration 	,dccw
		Display Switch 	,displayswitch
		DocumentsLibrary,shell:DocumentsLibrary
		Downloads,shell:Downloads
		DpapiKeys,shell:DpapiKeys
		Driver Verifier Manager 	,verifier
		EFS Wizard 	,rekeywiz
		Ease of Access Center 	,utilman
		Event Viewer 	,eventvwr.msc
		Font Viewer 	,fontview
		Fonts,shell:Fonts
		Game Controllers 	,joy.cpl
		GameTasks,shell:GameTasks
		Games,shell:Games
		History,shell:History
		HomeGroupCurrentUserFolder,shell:HomeGroupCurrentUserFolder
		HomeGroupFolder,shell:HomeGroupFolder
		IExpress Wizard ,iexpress
		ISCSI Initiator Configuration Tool 	,iscsicpl
		ImplicitAppShortcuts,shell:ImplicitAppShortcuts
		Internet Explorer ,iexplore
		Internet Options,inetcpl.cpl
		InternetFolder,shell:InternetFolder
		Language Pack Installer ,lpksetup
		Libraries,shell:Libraries
		Links,shell:Links
		Local AppData,shell:Local AppData
		Local Documents,shell:Local Documents
		Local Downloads,shell:Local Downloads
		Local Group Policy Editor 	,gpedit.msc
		Local Music,shell:Local Music
		Local Pictures,shell:Local Pictures
		Local Security Policy 	,secpol.msc
		Local Users and Groups 	,lusrmgr.msc
		Local Videos,shell:Local Videos
		LocalAppDataLow,shell:LocalAppDataLow
		Location Activity 	,locationnotifications
		MAPIFolder,shell:MAPIFolder
		Magnifier 	,magnify
		Malicious Software Removal Tool 	,mrt
		Manage Your File Encryption Certificates 	,rekeywiz
		Microsoft Management Console 	,mmc
		Microsoft Support Diagnostic Tool 	,msdt
		Mouse 	,main.cpl
		MusicLibrary,shell:MusicLibrary
		My Music,shell:My Music
		My Pictures,shell:My Pictures
		My Video,shell:My Video
		MyComputerFolder,shell:MyComputerFolder
		NAP Client Configuration 	,napclcfg.msc
		Narrator 	,narrator
		NetHood,shell:NetHood
		Network Connections 	,ncpa.cpl
		NetworkPlacesFolder,shell:NetworkPlacesFolder
		New Scan Wizard 	,wiaacmgr
		Notepad 	,notepad
		ODBC Data Source Administrator 	,odbcad32
		ODBC Driver Configuration 	,odbcconf
		OEM Links,shell:OEM Links
		On-Screen Keyboard 	,osk.exe
		OneDrive,shell:OneDrive
		OneDriveCameraRoll,shell:OneDriveCameraRoll
		OneDriveDocuments,shell:OneDriveDocuments
		OneDriveMusic,shell:OneDriveMusic
		OneDrivePictures,shell:OneDrivePictures
		Original Images,shell:Original Images
		Paint 	,mspaint
		Pen and Touch 	,tabletpc.cpl
		People Near Me 	,collab.cpl
		Performance Monitor 	,perfmon.msc
		Performance Options 	,systempropertiesperformance
		Personal,shell:Personal
		Phone Dialer 	,dialer
		Phone and Modem 	,telephon.cpl
		PhotoAlbums,shell:PhotoAlbums
		PicturesLibrary,shell:PicturesLibrary
		Playlists,shell:Playlists
		Power Options 	,powercfg.cpl
		Presentation Settings 	,presentationsettings
		Print Management 	,printmanagement.msc
		PrintHood,shell:PrintHood
		Printer Migration 	,printbrmui
		Printer User Interface 	,printui
		PrintersFolder,shell:PrintersFolder
		Private Character Editor 	,eudcedit
		Problem Steps Recorder 	,psr
		Profile,shell:Profile
		ProgramFiles,shell:ProgramFiles
		ProgramFilesCommon,shell:ProgramFilesCommon
		ProgramFilesCommonX64,shell:ProgramFilesCommonX64
		ProgramFilesCommonX86,shell:ProgramFilesCommonX86
		ProgramFilesX64,shell:ProgramFilesX64
		ProgramFilesX86,shell:ProgramFilesX86
		Programs,shell:Programs
		Programs and Features 	,appwiz.cpl
		Protected Content Migration 	,dpapimig
		Public,shell:Public
		PublicAccountPictures,shell:PublicAccountPictures
		PublicGameTasks,shell:PublicGameTasks
		PublicLibraries,shell:PublicLibraries
		Quick Launch,shell:Quick Launch
		Recent,shell:Recent
		Recorded Calls,shell:Recorded Calls
		RecordedTVLibrary,shell:RecordedTVLibrary
		RecycleBinFolder,shell:RecycleBinFolder
		Region and Language 	,intl.cpl
		Registry Editor 	,regedit
		Registry Editor 32 	,regedt32
		Remote Access Phonebook 	,rasphone
		Remote Desktop Connection 	,mstsc
		Resource Monitor 	,resmon
		ResourceDir,shell:ResourceDir
		Resultant Set of Policy 	,rsop.msc
		Retail Demo,shell:Retail Demo
		Ringtones,shell:Ringtones
		Roamed Tile Images,shell:Roamed Tile Images
		Roaming titles,shell:Roaming Tiles
		SAM Lock Tool 	,syskey
		SQL Server Client Network Utility 	,cliconfg
		SavedGames,shell:SavedGames
		SavedPictures,shell:SavedPictures
		SavedPicturesLibrary,shell:SavedPicturesLibrary
		Screen Resolution 	,desk.cpl
		Screen Saver photos,c:\windows\system32\photoscreenSaver.scr
		SearchHistoryFolder,shell:SearchHistoryFolder
		SearchHomeFolder,shell:SearchHomeFolder
		SearchTemplatesFolder,shell:SearchTemplatesFolder
		Searches,shell:Searches
		Securing the Windows Account Database 	,syskey
		SendTo,shell:SendTo
		Services 	,services.msc
		Set Program Access and Computer Defaults 	,computerdefaults
		Share Creation Wizard 	,shrpubw
		Shared Folders 	,fsmgmt.msc
		Signout 	,logoff
		Snipping Tool 	,snippingtool
		Sound 	,mmsys.cpl
		Sound recorder 	,soundrecorder
		Start Menu,shell:Start Menu
		StartMenuAllPrograms,shell:StartMenuAllPrograms
		Startup,shell:Startup
		Sticky Notes 	,stikynot
		Stored User Names and Passwords 	,credwiz
		Sync Center 	,mobsync
		SyncCenterFolder,shell:SyncCenterFolder
		SyncResultsFolder,shell:SyncResultsFolder
		SyncSetupFolder,shell:SyncSetupFolder
		System,shell:System
		System Configuration 	,msconfig
		System Configuration Editor 	,sysedit
		System Information 	,msinfo32
		System Properties 	,sysdm.cpl
		System Properties (Advanced Tab) 	,systempropertiesadvanced
		System Properties (Computer Name Tab) 	,systempropertiescomputername
		System Properties (Hardware Tab) 	,systempropertieshardware
		System Properties (Remote Tab) 	,systempropertiesremote
		System Properties (System Protection Tab) 	,systempropertiesprotection
		System Restore 	,rstrui
		SystemCertificates,shell:SystemCertificates
		SystemX86,shell:SystemX86
		Task Manager 	,taskmgr
		Task Scheduler 	,taskschd.msc
		Templates,shell:Templates
		ThisDeviceFolder,shell:ThisDeviceFolder
		ThisPCDesktopFolder,shell:ThisPCDesktopFolder
		Trusted Platform Module (TPM) Management 	,tpm.msc
		Turn Windows features on or off 	,optionalfeatures
		User Account Control Settings 	,useraccountcontrolsettings
		User Pinned,shell:User Pinned
		UserProfiles,shell:UserProfiles
		UserProgramFiles,shell:UserProgramFiles
		UserProgramFilesCommon,shell:UserProgramFilesCommon
		UsersFilesFolder,shell:UsersFilesFolder
		UsersLibrariesFolder,shell:UsersLibrariesFolder
		Utility Manager 	,utilman
		Versione Windows,winver
		VideosLibrary,shell:VideosLibrary
		Virtual Machines,shell:Virtual Machines
		Volume Mixer 	,sndvol
		WMI Management,wmimgmt.msc
		Windows,shell:Windows
		Windows Action Center 	,wscui.cpl
		Windows Activation Client 	,slui
		Windows Anytime Upgrade Results 	,windowsanytimeupgraderesults
		Windows Disc Image Burning Tool 	,isoburn
		Windows Explorer 	,explorer
		Windows Fax and Scan 	,wfs
		Windows Firewall 	,firewall.cpl
		Windows Firewall with Advanced Security 	,wf.msc
		Windows Journal 	,journal
		Windows Media Player 	,wmplayer
		Windows Memory Diagnostic Scheduler 	,mdsched
		Windows Mobility Center 	,mblctr
		Windows Picture Acquisition Wizard 	,wiaacmgr
		Windows PowerShell 	,powershell
		Windows PowerShell ISE 	,powershell_ise
		Windows Remote Assistance 	,msra
		Windows Repair Disc 	,recdisc
		Windows Script Host 	,wscript
		Windows Update 	,wuapp
		Windows Update Standalone Installer,wusa
		WordPad 	,write
		XPS Viewer 	,xpsrchvw
		ENDTEXT

		*non TESTES ok
		*Quick Assist ,{1AC14E77-02E7-4E5D-B744-2EB1AE519887}\quickassist.exe
		*Microsoft visual foxpro 9,{7C5A40EF-A0FB-4BFC-874A-C0F2E0B9FA8E}\Microsoft Visual Foxpro 9\vfp.exe
		*Mathematic typing panel,{6D809377-6AF0-444B-8957-A3773F02200E}\Common Files\Microsoft Shared\lnk\mip.exe
		*
		Create Cursor ycurs (xApplication c(50),xcommand c(150))
		Local m.x,m.y
		For i=1 To Memlines(m.myvar)
			m.x=Getwordnum(Mline(m.myvar,i),1,",")
			m.y=Getwordnum(Mline(m.myvar,i),2,",")
			Insert Into ycurs Values( m.x,m.y)
		Endfor
		Sele ycurs
		*brow
		Locate
	Endproc

	Procedure Init
		_Screen.WindowState=1
		This.Caption="Windows -1703- Applications ("+Trans(Reccount())+") - click on any row to run the destination."
		This.grid1.column1.Width=This.Width-2
		This.BorderStyle=0
		This.xs=""
	Endproc

	Procedure Destroy
		Clea Events
	Endproc

	Procedure grid1.Init
		With This
			.RecordSource="ycurs"
			.RecordSourceType=1
			.Themes=.F.
			.GridLines=0
			.DeleteMark=.F.
			.RowHeight=23
			.column2.Visible=.F.
			.column1.Width=656
			.MousePointer=15
			.SetAll("DynamicBackColor","IIF(MOD(RECNO( ), 2)=0,RGB(200,206,180),RGB(205,215,155))", "Column")
			.FontBold=.T.
			.FontSize=12
			.SetAll("fontbold",.T.,"header")
			.SetAll("fontsize",14,"header")
			.column1.header1.Caption="win10 Applications & special Folders"
			.column1.header1.ForeColor=Rgb(255,128,0)
			.HeaderHeight=28
			Locate
			.Refresh
			Bindevent(.column1.text1,"mousedown",Thisform,"my")
		Endwith
	Endproc

	Procedure label1.RightClick
		_Cliptext=Allt(This.Caption)
	Endproc

	Procedure command1.Click
		Try
			Local m.x
			m.x="shell:Appsfolder"
			Thisform.label1.Caption="Windows Apps"
			Local m.result
			m.result = ShellExecute(0, "open", "explorer.exe ",m.x,"",1)

			If result<=32
				Messagebox("Fail to run!",16+4096,'',1200)
			Endi

		Catch
			Messagebox("An error was occured!",16+4096,"Error",1200)
		Endtry
	Endproc

	Procedure shape1.Click
		Thisform.grid1.SetFocus
		Sele ycurs
		rec=Recno()
		Locate For Lower(Thisform.xs) $ Lower(xApplication) And Recno()>rec
		If Found()
			Thisform.grid1.Refresh
		Else
			Wait Window "End search" Nowait
			Locate
		Endi
	Endproc

	Procedure shape2.Click
		Thisform.xs=Inputbox("Search for","",Thisform.xs)
		If Empty(Thisform.xs)
			Return .F.
		Endi
		Thisform.grid1.SetFocus
		Sele ycurs
		rec=Recno()
		Locate For Lower(Thisform.xs) $ Lower(xApplication) And Recno()>rec
		If Found()
			Thisform.grid1.Refresh
		Else
			Wait Window "End search" Nowait
			Locate
		Endi
	Endproc

Enddefine
*
*-- EndDefine: ywinApps0


Digging in windows10 mine

Click on code to select [then copy] -click outside to deselect


*2* in the same registry this code gathers all windows Apps and run the clicked one.
*created on 26 of october 2017

If !_vfp.StartMode=0
	On Shutdown Quit
Endi

Publi yform
yform=Newobject("yAll_Apps")
yform.Show
Read Events
Retu
*
Define Class yAll_Apps As Form
	BorderStyle = 0
	Top = 0
	Left = 0
	Height = 434
	Width = 662
	ShowWindow = 2
	DoCreate = .T.
	Caption = ""
	MaxButton = .F.
	WindowState = 0
	xs = .F.

	Add Object grid1 As Grid With ;
		Anchor = 0, ;
		Height = 385, ;
		Left = 10, ;
		ReadOnly = .T., ;
		Top = 5, ;
		Width = 622, ;
		Name = "Grid1"

	Add Object label1 As Label With ;
		FontSize = 10, ;
		WordWrap = .T., ;
		Alignment = 2, ;
		BackStyle = 0, ;
		Caption = "", ;
		Height = 37, ;
		Left = 48, ;
		Top = 395, ;
		Width = 553, ;
		ForeColor = Rgb(255,0,0), ;
		Name = "Label1"

	Add Object command1 As CommandButton With ;
		AutoSize = .T., ;
		Top = 396, ;
		Left = 0, ;
		Height = 27, ;
		Width = 49, ;
		FontBold = .T., ;
		Caption = "Apps", ;
		MousePointer = 15, ;
		BackColor = Rgb(128,255,0), ;
		Name = "Command1"

	Add Object shape1 As Shape With ;
		Top = 398, ;
		Left = 638, ;
		Height = 15, ;
		Width = 15, ;
		Curvature = 99, ;
		MousePointer = 15, ;
		ToolTipText = "Repeat", ;
		BackColor = Rgb(0,255,0), ;
		Name = "Shape1"

	Add Object shape2 As Shape With ;
		Top = 398, ;
		Left = 615, ;
		Height = 15, ;
		Width = 15, ;
		Curvature = 99, ;
		MousePointer = 15, ;
		ToolTipText = "sEARCH FOR A STRING", ;
		BackColor = Rgb(255,0,0), ;
		Name = "Shape2"

	Procedure my
		Lparameters nButton, nShift, nXCoord, nYCoord
		Sele ycurs
		Try
			Local m.x
			m.x="shell:Appsfolder\"+Allt(xcommand)
			Thisform.label1.Caption=Allt(xApplication)+":"+Allt(xcommand)
			Local m.result
			m.result = ShellExecute(0, "open", "explorer.exe ",m.x,"",1)

			If result<=32
				Messagebox("Fail to run!",16+4096,'',1200)
			Endi

		Catch
			Messagebox("An error was occured!",16+4096,"Error",1200)
		Endtry
	Endproc

	Procedure Load
		&&shellexecute
		Declare Integer ShellExecute In SHELL32.Dll Integer nWinHandle,;
			STRING cOperation,;
			STRING cFileName,;
			STRING cParameters,;
			STRING cDirectory,;
			INTEGER nShowWindow

		Close Data All

		Set Memowidth To 8192
		Local m.myvar
		TEXT to m.myvar noshow
		3D Builder,Microsoft.3DBuilder_8wekyb3d8bbwe!App
		Calculator,Microsoft.WindowsCalculator_8wekyb3d8bbwe!App
		News,Microsoft.BingNews_8wekyb3d8bbwe!AppexNews
		Alarms and clock,Microsoft.WindowsAlarms_8wekyb3d8bbwe!App
		Performances analyser,Microsoft.AutoGenerated.{67DEE369-C509-982D-F248-ABCEA8A27352}
		WINDOWS UPDATE,Microsoft.AutoGenerated.{E21297FF-6254-8C2F-0B70-ABCD6703E23F}
		tricks(Astuces),Microsoft.GetStarted_8wekyb3d8bbwe!App
		Calendar,microsoft.windowscommunicationsapps_8wekyb3d8bbwe!microsoft.windowslive.calendar
		Camera,Microsoft.Windowscamera_8wekyb3d8bbwe!App
		Maps,Microsoft.WindowsMaps_8wekyb3d8bbwe!App
		This PC,Microsoft.Windows.Computer
		Visual keyboard,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\osk.exe
		system config  ,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\msconfig.exe
		connection bureau à distance,Microsoft.Windows.RemoteDesktop
		Contacts,Microsoft.People_8wekyb3d8bbwe!x4c7a3b7dy2188y46d4ya362y19ac5a5805e5x
		Cortana,Microsoft.Windows.Cortana_cw5n1h2txyewy!CortanaUI
		Courier,Microsoft.Windowscommunicationsapps_8wekyb3d8bbwe!microsoft.windowslive.mail
		Memory windows diagnostic,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\MdSched.exe
		Voice Recorder,Microsoft.WindowsSoundRecorder_8wekyb3d8bbwe!App
		Windows Explorer,Microsoft.Windows.Explorer
		Execute,Microsoft.Windows.Shell.RunDialog
		EVENTS OBSERVER,Microsoft.AutoGenerated.{245F8F81-DE65-1904-B2D3-1D7B3B99AF6D}
		Help assist,Windows.ContactSupport_cw5n1h2txyewy!App
		Films et TV,Microsoft.ZuneVideo_8wekyb3d8bbwe!Microsoft.ZuneVideo
		Finances,Microsoft.BingFinance_8wekyb3d8bbwe!AppexFinance
		Functionalities,Microsoft.FodHelper
		PC management,Microsoft.AutoGenerated.{E28FB7A9-B922-0A8D-14A7-F4A12E61B8C2}
		Task manager,Microsoft.AutoGenerated.{F9BA49F8-6791-D89D-CCEC-71D3D9C0C7AE}
		Printing management,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\printmanagement.msc
		groove music,Microsoft.ZuneMusic_8wekyb3d8bbwe!Microsoft.ZuneMusic
		System information,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\msinfo32.exe
		Internet explorer,Microsoft.InternetExplorer.default
		MSDOS,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\cmd.exe
		windows mediaplayer,Microsoft.Windows.Mediaplayer32
		Magnify,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\Magnify.exe
		Messages,Microsoft.Messaging_8wekyb3d8bbwe!x27e26f40ye031y48a6yb130yd1f20388991ax
		Microsoft Edge,Microsoft.MicrosoftEdge_8wekyb3d8bbwe!MicrosoftEDge
		Mixed Reality Viewer,Microsoft.Microsoft3DViewer_8wekyb3d8bbwe!Microsoft.Microsoft3DViewer
		Meteo,Microsoft.BingWeather_8wekyb3d8bbwe!App
		MOBILE ASSISTANT,Microsoft.WindowsPhone_8wekyb3d8bbwe!CompanionApp.App
		Narrator,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\narrator.exe
		Notepad,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\notepad.exe
		Disc Cleaner,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\cleanmgr.exe
		Snippingtool,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\SnippingTool.exe
		PAINT,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\mspaint.exe
		ONE NOTE,Microsoft.Office.OneNote_8wekyb3d8bbwe!microsoft.onenoteim
		Optional functionalities,Microsoft.FodHelper
		PAINT 3D,Microsoft.MSPaint_8wekyb3d8bbwe!Microsoft.MSPaint
		CONTROL PANEL,Microsoft.Windows.Controlpanel
		SETTINGS,windows.immersivecontrolpanel_cw5n1h2txyewy!microsoft.windows.immersivecontrolpanel
		PHOTOS,microsoft.Windows.Photos_8wekyb3d8bbwe!App
		Resources monitor,Microsoft.AutoGenerated.{2486123E-0FE5-4788-B86E-2A11B662F89B}
		WIn mixed reality,Microsoft.Windows.HolographicFirstRun_cw5n1h2txyewy!App
		Task scheduler,Microsoft.AutoGenerated.{AB568050-88B9-C154-AE66-C3E1E4EF4479}
		WIN VOICE RECOGNITION,Microsoft.AutoGenerated.{119E4E64-B444-B876-1F09-80182D07FD21}
		Services,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\services.msc
		Skype,Microsoft.SkypeApp_kzf8qxf38zg5c!App
		Sport,Microsoft.BingSports_8wekyb3d8bbwe!AppexSports
		Stycky notes,Microsoft.MicrosoftStickynotes_8wekyb3d8bbwe!App
		Charmap,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\charmap.exe
		Telecopy,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\WFS.exe
		Use actions recorder,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\psr.exe
		Win PowerShell,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\WindowsPowershell\v1.0\powershell.exe
		Windows Store,Microsoft.WindowsStore_8wekyb3d8bbwe!App
		Windows Defender Center,Microsoft.Windows.SecHealthUi_cw5n1h2txyewy!SecHealthUI
		XBOX,Microsoft.XboxApp_8wekyb3d8bbwe!Microsoft.XboxApp
		XPS viewer,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\xpsrchvw.exe

		ENDTEXT

		*non TESTES ok
		*Quick Assist ,{1AC14E77-02E7-4E5D-B744-2EB1AE519887}\quickassist.exe
		*Microsoft visual foxpro 9,{7C5A40EF-A0FB-4BFC-874A-C0F2E0B9FA8E}\Microsoft Visual Foxpro 9\vfp.exe
		*Mathematic typing panel,{6D809377-6AF0-444B-8957-A3773F02200E}\Common Files\Microsoft Shared\lnk\mip.exe

		Create Cursor ycurs (xApplication c(50),xcommand c(150))
		Local m.x,m.y
		For i=1 To Memlines(m.myvar)
			m.x=Getwordnum(Mline(m.myvar,i),1,",")
			m.y=Getwordnum(Mline(m.myvar,i),2,",")
			Insert Into ycurs Values( m.x,m.y)
		Endfor
		Sele ycurs
		*brow
		Locate
	Endproc

	Procedure Init
		_Screen.WindowState=1
		This.Caption="Windows -1703- Applications ("+Trans(Reccount())+") - click on any row to run the destination."
		This.grid1.column1.Width=This.Width-20
		This.BorderStyle=0
		This.xs=""
	Endproc

	Procedure Destroy
		Clea Events
	Endproc

	Procedure grid1.Init
		With This
			.RecordSource="ycurs"
			.RecordSourceType=1
			.Themes=.F.
			.GridLines=0
			.DeleteMark=.F.
			.RowHeight=23
			.column2.Visible=.F.
			.column1.Width=600
			.MousePointer=15
			.SetAll("DynamicBackColor","IIF(MOD(RECNO( ), 2)=0,RGB(200,206,180),RGB(195,203,215))", "Column")
			.FontBold=.T.
			.FontSize=12
			.SetAll("fontbold",.T.,"header")
			.SetAll("fontsize",14,"header")
			.column1.header1.Caption="Applications"
			.column1.header1.ForeColor=Rgb(255,128,0)
			.HeaderHeight=28
			Locate
			.Refresh
			Bindevent(.column1.text1,"mousedown",Thisform,"my")
		Endwith
	Endproc

	Procedure label1.RightClick
		_Cliptext=Allt(This.Caption)
	Endproc

	Procedure command1.Click
		Try
			Local m.x
			m.x="shell:Appsfolder"
			Thisform.label1.Caption="Windows Apps"
			Local m.result
			m.result = ShellExecute(0, "open", "explorer.exe ",m.x,"",1)

			If result<=32
				Messagebox("Fail to run!",16+4096,'',1200)
			Endi

		Catch
			Messagebox("An error was occured!",16+4096,"Error",1200)
		Endtry
	Endproc

	Procedure shape1.Click
		Thisform.grid1.SetFocus
		Sele ycurs
		rec=Recno()
		Locate For Lower(Thisform.xs) $ Lower(xApplication) And Recno()>rec
		If Found()
			Thisform.grid1.Refresh
		Else
			Wait Window "End search" Nowait
			Locate
		Endi
	Endproc

	Procedure shape2.Click
		Thisform.xs=Inputbox("Search for","",Thisform.xs)
		If Empty(Thisform.xs)
			Return .F.
		Endi
		Thisform.grid1.SetFocus
		Sele ycurs
		rec=Recno()
		Locate For Lower(Thisform.xs) $ Lower(xApplication) And Recno()>rec
		If Found()
			Thisform.grid1.Refresh
		Else
			Wait Window "End search" Nowait
			Locate
		Endi
	Endproc

Enddefine
*
*-- EndDefine: yAll_Apps



Digging in windows10 mine

Click on code to select [then copy] -click outside to deselect


*3*
*special folders tested on windows10 version 1703 ( creator update ).
*created on 26 of october 2017
*note: maybe all special folders exist on PC, if yes the explorer point to "documents" folder (not found).

publi yform
yform=newObject("yspecialFolders")
yform.show
read events
retu

*
DEFINE CLASS yspecialFolders AS form
	BorderStyle = 3
	Height = 383
	Width = 753
	AutoCenter = .T.
	ShowWindow=2
	Caption = "Some special folders"
	Name = "Form1"

	ADD OBJECT grid1 AS grid WITH ;
		Anchor = 15, ;
		Height = 385, ;
		Left = 2, ;
		Top = 6, ;
		Width = 754, ;
		Name = "Grid1"

	PROCEDURE my
		LPARAMETERS nButton, nShift, nXCoord, nYCoord
		sele ycurs
		messagebox(xcommand,0+32+4096,'command line',1000)
		try
		 ShellExecute(0, "open","explorer.exe",xcommand,"",1)
		catch
		messagebox("An error was occured!",16+4096,"Error",1200)
		*note : if explorer fails to open destination it opens the documents folder also
		endtry
	ENDPROC

	PROCEDURE Load
		&&shellexecute
		DECLARE INTEGER ShellExecute IN SHELL32.DLL INTEGER nWinHandle,;
		                                            STRING cOperation,;
		                                            STRING cFileName,;
		                                            STRING cParameters,;
		                                            STRING cDirectory,;
		                                            INTEGER nShowWindow
		close data all
		set memowidth to 8192
		LOCAL M.MYVAR
		TEXT TO M.MYVAR PRETEXT 7 NOSHOW
		shell:AccountPictures	,Account Pictures
		shell:AddNewProgramsFolder	,Add New Programs folder
		shell:Administrative Tools	,Administrative Tools
		shell:AppData	,C:\Users\user\AppData\Roaming
		shell:Application Shortcuts	,C:\Users\user\AppData\Local\Microsoft\Windows\Application Shortcuts
		shell:AppsFolder	,The virtual folder which stores all installed Modern apps
		shell:AppUpdatesFolder	,The "Installed Updates" Control panel item
		shell:Cache	,IE's cache folder (Temporary Internet Files)
		shell:Camera Roll	,Camera Roll
		shell:CD Burning	,Temporary Burn Folder
		shell:ChangeRemoveProgramsFolder	,The "Uninstall a program" Control panel item
		shell:Common Administrative Tools	,The Administrative Tools folder for all users
		shell:Common AppData	,The C:\ProgramData folder (%ProgramData%)
		shell:Common Desktop	,Public Desktop
		shell:Common Documents	,Public Documents
		shell:Common Programs	,All Users Programs, which are part of Start menu. Still used by the Start screen
		shell:Common Start ,Menu	All Users Start Menu folder, same as above
		shell:Common Startup	,The Startup folder, used for all users
		shell:Common Templates	,Same as above, but used for new documents templates, e.g. by Microsoft Office
		shell:CommonDownloads	,Public Downloads
		shell:CommonMusic	,Public Music
		shell:CommonPictures	,Public Pictures
		shell:CommonRingtones	,CommonRingtones
		shell:CommonVideo	,Public Videos
		shell:ConflictFolder	,The Control Panel\All Control Panel Items\Sync Center\Conflicts item
		shell:ConnectionsFolder	,The Control Panel\All Control Panel Items\Network Connections item
		shell:Contacts	,Contacts folder (Address book)
		shell:ControlPanelFolder	,Control Panel
		shell:Cookies	,The folder with IE's cookies
		shell:CredentialManager	,C:\Users\<username>\AppData\Roaming\Microsoft\Credentials
		shell:CryptoKeys	,C:\Users\<username>\AppData\Roaming\Microsoft\Crypto
		shell:CSCFolder	,This folder is broken in Windows 8/7, provides access to the Offline files item
		shell:Desktop	,Desktop
		shell:Device ,Metadata Store	C:\ProgramData\Microsoft\Windows\DeviceMetadataStore
		shell:DocumentsLibrary	,Documents library
		shell:Downloads	,Downloads folder
		shell:DpapiKeys	,C:\Users\<username>\AppData\Roaming\Microsoft\Protect
		shell:Favorites	,Favorites
		shell:Fonts	,C:\Windows\Fonts
		shell:Games	,The Games Explorer item
		shell:GameTasks,	C:\Users\<username>\AppData\Local\Microsoft\Windows\GameExplorer
		shell:History	,C:\Users\<username>\AppData\Local\Microsoft\Windows\History, IE's browsing history
		shell:HomeGroupCurrentUserFolder	,The Home Group folder for the current user
		shell:HomeGroupFolder	,The Home Group root folder
		shell:ImplicitAppShortcuts	,C:\Users\<username>\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch\User Pinned\ImplicitAppShortcuts
		shell:InternetFolder	,This shell command will start Internet Explorer
		shell:Libraries,	Libraries
		shell:Links	,The "Favorites" folder from the Explorer navigation pane.
		shell:Local AppData	,C:\Users\<username>\AppData\Local
		shell:LocalAppDataLow	,C:\Users\<username>\AppData\LocalLow
		shell:LocalizedResourcesDir,	This shell folder is broken since Windows 8 RTM
		shell:MAPIFolder	,Represents the Microsoft Outlook folder
		shell:MusicLibrary	,Music Library
		shell:My Music	,The "My Music" folder (not the Library)
		shell:My Pictures	,The "My Pictures" folder (not the Library)
		shell:My Video	,The "My Videos" folder (not the Library)
		shell:MyComputerFolder	,Computer/Drives view
		shell:NetHood	,C:\Users\<username>\AppData\Roaming\Microsoft\Windows\Network Shortcuts
		shell:NetworkPlacesFolder	,The Network Places folder which shows computers and devices on your network
		shell:OEM Links	,This shell command does nothing on my Windows 8.1 RTM
		shell:Original Images	,Same as above
		shell:Personal	,The "My Documents" folder (not the Library)
		shell:PhotoAlbums	,Saved slideshows, seems to have not been implemented yet
		shell:PicturesLibrary	,Pictures Library
		shell:Playlists	,Stores WMP Playlists
		shell:PrintersFolder	,The classic "Printers" folder (not 'Devices and Printers')
		shell:PrintHood	,C:\Users\<username>\AppData\Roaming\Microsoft\Windows\Printer Shortcuts
		shell:Profile	,The User profile folder
		shell:ProgramFiles	,Program Files
		shell:ProgramFilesCommon	,C:\Program Files\Common Files
		shell:ProgramFilesCommonX64,	C:\Program Files\Common Files - for Windows x64
		shell:ProgramFilesCommonX86,	C:\Program Files (x86)\Common Files - for Windows x64
		shell:ProgramFilesX64	,C:\Program Files - for Windows x64
		shell:ProgramFilesX86	,C:\Program Files (x86) - for Windows x64
		shell:Programs	,C:\Users\<username>\AppData\Roaming\Microsoft\Windows\Start Menu\Programs (Per-user Start Menu Programs folder)
		shell:Public	,C:\Users\Public
		shell:PublicAccountPictures	,C:\Users\Public\AccountPictures
		shell:PublicGameTasks	,C:\ProgramData\Microsoft\Windows\GameExplorer
		shell:PublicLibraries	,C:\Users\Public\Libraries
		shell:Quick Launch	,C:\Users\<username>\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch
		shell:Recent	,The "Recent Items" folder (Recent Documents)
		shell:RecordedTVLibrary	,The "Recorded TV" Library
		shell:RecycleBinFolder	,The Recycle Bin folder
		shell:ResourceDir	,C:\Windows\Resources where visual styles are stored
		shell:Ringtones	,C:\Users\<username>\AppData\Local\Microsoft\Windows\Ringtones
		shell:Roamed Tile Images	,Does not work. Probably reserved for future.
		shell:Roaming Tiles	,C:\Users\<username>\AppData\Local\Microsoft\Windows\RoamingTiles
		shell:SavedGames	,Saved Games
		shell:Screenshots	,The folder for Win+Print Screen screenshots
		shell:Searches	,Saved Searches
		shell:SearchHistoryFolder,	C:\Users\<username>\AppData\Local\Microsoft\Windows\ConnectedSearch\History
		shell:SearchHomeFolder	,Windows Search UI
		shell:SearchTemplatesFolder,	C:\Users\winaero\AppData\Local\Microsoft\Windows\ConnectedSearch\Templates
		shell:SendTo	,The folder with items that you can see in the "Send to" menu
		shell:SkyDrive	,The SkyDrive folder
		shell:SkyDriveCameraRoll	,The Camera Roll images folder inside the SkyDrive folder
		shell:SkyDriveDocuments	,The Documents folder inside the SkyDrive folder
		shell:SkyDrivePictures	,The Pictures folder inside the SkyDrive folder
		shell:Start Menu	,C:\Users\<username>\AppData\Roaming\Microsoft\Windows\Start Menu (Per-user Start Menu folder)
		shell:Startup	,Per-user Startup folder
		shell:SyncCenterFolder	,Control Panel\All Control Panel Items\Sync Center
		shell:SyncResultsFolder	,Control Panel\All Control Panel Items\Sync Center\Sync Results
		shell:SyncSetupFolder	,Control Panel\All Control Panel Items\Sync Center\Sync Setup
		shell:System	,C:\Windows\System32
		shell:SystemCertificates	,C:\Users\<username>\AppData\Roaming\Microsoft\SystemCertificates
		shell:SystemX86	,C:\Windows\SysWOW64 -Windows x64 only
		shell:Templates	,C:\Users\<username>\AppData\Roaming\Microsoft\Windows\Templates
		shell:ThisPCDesktopFolder	,The Desktop folder
		shell:User Pinned	,Pinned items for Taskbar and Start screen, C:\Users\<username>\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch\User Pinned
		shell:UserProfiles	,C:\Users, the users folder where the user profiles are stored
		shell:UserProgramFiles	,C:\Users\winaero\AppData\Local\Programs
		shell:UserProgramFilesCommon	,C:\Users\winaero\AppData\Local\Programs\Common
		shell:UsersFilesFolder	,The current user profile
		shell:UsersLibrariesFolder	,Libraries
		shell:VideosLibrary	Videos ,library
		shell:Windows	,C:\Windows
		ENDTEXT

		create cursor ycurs (xcommand c(50), xtitle c(120))
		local m.x,m.y
		for i=1 to memlines(m.myvar)
		m.x=allt(getwordnum( mline(m.myvar,i),1,","))
		m.y=allt(getwordnum( mline(m.myvar,i),2,","))
		insert into ycurs values (m.x ,m.y )
		endfor
		sele ycurs
		*brow
	ENDPROC

	PROCEDURE Init
		this.caption="some special folders ("+trans(reccount())+") - click on any row to run the destination."
	ENDPROC

	PROCEDURE Destroy
		clea events
	ENDPROC

	PROCEDURE grid1.Init
		with this
		.recordsource="ycurs"
		.recordsourcetype=1
		.themes=.f.
		.gridlines=0
		.deletemark=.f.
		.rowHeight=23
		.column1.visible=.f.
		.mousepointer=15
		.SetAll("DynamicBackColor","IIF(MOD(RECNO( ), 2)=0,RGB(200,206,180),RGB(255,255,255))", "Column")
		.fontbold=.t.
		.SetAll("fontbold",.T.,"header")
		.SetAll("fontsize",14,"header")
		.column2.header1.forecolor=rgb(255,128,0)
		.headerHeight=28
		locate
		.refresh
		bindevent(.column2.text1,"mousedown",thisform,"my")
		endwith
	ENDPROC

ENDDEFINE
*
*-- EndDefine: yspecialFolders


Digging in windows10 mine

Click on code to select [then copy] -click outside to deselect



*4*created on 26 of october 2017
*extract all icons given by  index in 24  win10 (version 1703) dlls....(dlls tested exists).
*method uses APIs exclusively(read previous post with key=extractIcon).
*Note: extractIcon API extracts only 32x32 format icons (color depth=32)

*this code generates  2039 icons format 32x32 in folder yall_win10\icons" created in source starting code.
*this gives an opportunity to have 2039 icons under the hand for developping apps.

Do yDeclare

Set Safe Off
Publi m.yrep
m.yrep=Addbs(Justpath(Sys(16,1)))

Try
	If ! Directory(m.yrep+"yall_win10_icons")
		Md (m.yrep+"yall_win10_icons")
	Else
		Wait Window "cleaning folder icons...." Nowait
		Dele File (m.yrep+"yall_win10_icons\*.*")    &&recycle
		Wait Clea
	Endi
Catch
	Messagebox("An error was occured when deleting images in "+m.yrep+"yall_win10_icons\...do this operation manually!",16+4096,"error",2000)
Endtry
Create Cursor ycurs (ypath c(50))
Insert Into ycurs Values("%systemroot%\system32\imageres.dll")  &&contains lots of icons, used almost everywhere in Windows 10. It has icons for different types of folders, hardware devices, actions, and so on.
Insert Into ycurs Values("%systemroot%\system32\shell32.dll ")  && also has lots of icons used in various parts of Windows 10.
Insert Into ycurs Values("%systemroot%\system32\pifmgr.dll")   &&contains old-style icons that were used for all kinds of things, since Windows 95.
Insert Into ycurs Values("%systemroot%\explorer.exe")          &&has a few icons used mainly in File Explorer.
Insert Into ycurs Values("%systemroot%\system32\accessibilitycpl.dll") &&has a set of icons that are used mainly for the accessibility features in Windows 10.
Insert Into ycurs Values("%systemroot%\system32\ddores.dll")    &&contains icons for hardware devices and resources
Insert Into ycurs Values("%systemroot%\system32\gameux.dll ")   &&has a few gaming related icons.
Insert Into ycurs Values("%systemroot%\system32\moricons.dll")  &&is another file that contains old-style icons, used by Microsoft in old Windows versions.
Insert Into ycurs Values("%systemroot%\system32\mmcndmgr.dll")  &&is yet another file with old looking icons, which we believe were designed mainly for computer management related settings.
Insert Into ycurs Values("%systemroot%\system32\mmres.dll")    && has icons with various audio resources, like speakers, headphones, microphones ..
Insert Into ycurs Values("%systemroot%\system32\netcenter.dll") &&has icons for network related settings and features.
Insert Into ycurs Values("%systemroot%\system32\netshell.dll ") &&contains icons for all kinds of network connections and associated hardware or technologies. For instance, inside it, you'll find icons for Bluetooth or for wireless routers.
Insert Into ycurs Values("%systemroot%\system32\networkexplorer.dll")  &&dll file with a few network related icons.
Insert Into ycurs Values("%systemroot%\system32\pnidui.dll")    &&has icons for network related settings (Ethernet or wireless status, network locations, etc.).
Insert Into ycurs Values("%systemroot%\system32\sensorscpl.dll")&& has a few icons for different kinds of sensors. While most of them look similar, their details indicate things like temperature, power, wind etc.
Insert Into ycurs Values("%systemroot%\system32\setupapi.dll" )  && has icons used for the setup wizard of various hardware devices.
Insert Into ycurs Values("%systemroot%\system32\wmploc.dll"  )   && contains icons used for media devices, files, folders, and so on.
Insert Into ycurs Values("%systemroot%\system32\wpdshext.dll" )   && has icons for some portable devices and battery indicators.
Insert Into ycurs Values("%systemroot%\system32\compstui.dll")   && includes various classic icons from older versions of Windows.
Insert Into ycurs Values("%systemroot%\system32\ieframe.dll")    && contains the icons used in Internet Explorer.
Insert Into ycurs Values("%systemroot%\system32\dmdskres.dll")   && contains the icons for disk management.
Insert Into ycurs Values("%systemroot%\system32\dsuiext.dll")    && includes icons for network services.
Insert Into ycurs Values("%systemroot%\system32\mstscax.dll")    && stores icons used for remote desktop connections.
Insert Into ycurs Values("%systemroot%\system32\wiashext.dll")   && has icons for various imaging hardware devices, like scanners and cameras.

Local m.lcdest,m.oo
m.oo=m.yrep+"yall_win10_icons"
Sele ycurs
Scan

	Local lcfile,i,x,lcfile
	m.lcfile=ypath
	If Empty(ypath)
		Loop
	Endi
	i=0
	m.x=.T.

	Do While m.x=.T.
		m.lcdest= m.yrep+"yall_win10_icons\"+Juststem(m.lcfile)+"_"+Trans(i)+'.ico'
		m.x=IconExtract(m.lcfile,m.lcdest,i)
		Wait Window (Justfname(m.lcdest)) At Srows()/2,Scols()/2-20 Nowait
		If !File(m.lcdest)
			Exit
		Else
			i=i+1
		Endi
	Enddo
Endscan
Clear Dlls 'ExtractIcon', 'OleCreatePictureIndirect', 'DestroyIcon'

Run/N explorer &oo
Retu

Procedure IconExtract
	Lparameters tcSourceFile As String, tcTargetFile As String, tnIconIndex As Integer
	Assert File(tcSourceFile)
	Local lnIconHandle As Integer, loIconReference As Object
	tnIconIndex = Iif(Vartype(tnIconIndex) = 'N', tnIconIndex, 0)

	lnIconHandle = ExtractIcon(0, tcSourceFile, tnIconIndex)
	If lnIconHandle # 0
		tcStructure = Long2String(16) + Long2String(3) + Long2String(lnIconHandle) + Long2String(0)
		tcIdentifier = Replicate(Chr(0), 8) + Chr(0xC0)+ Replicate(Chr(0), 6) + Chr(0x46)
		loIconReference = 0
		OleCreatePictureIndirect(@tcStructure, @tcIdentifier, 1, @loIconReference)
		If Vartype(loIconReference) = 'O'
			If SavePicture(loIconReference, tcTargetFile)
				*icon successful extracted
			Endif
		Else
			Messagebox('OleCreatePictureIndirect() error')
		Endif
		DestroyIcon(lnIconHandle)
	Else
		*	Messagebox('ExtractIcon() error')
	Endif
	Return

Function Long2String
	Lparameters tnLong
	tnLong = Int(tnLong)
	Return Chr(Bitand(tnLong, 255)) + ;
		CHR(Bitand(Bitrshift(tnLong, 8), 255)) + ;
		CHR(Bitand(Bitrshift(tnLong, 16), 255)) + ;
		CHR(Bitand(Bitrshift(tnLong, 24), 255))
Endfunc

Procedure yDeclare
	Declare Integer ExtractIcon In shell32 Integer, String, Integer
	Declare Long OleCreatePictureIndirect In oleaut32 String @, String @, Long, Object @
	Declare SHORT DestroyIcon In user32 Integer
Endproc


*tip: rightclick on any file or link  and go to dialog...properties...change icon option and type one of the 24 dlls above.
*you can see in the dialog all icons drawn here(can select one to change link icon)


this manual  method can be applied as well to a shortcut or EXE...

this manual method can be applied as well to a shortcut or EXE...

Click on code to select [then copy] -click outside to deselect


*5* created on tuesday  31 of october 2017
*!*	How to properly restart the Explorer shell in Windows
*!*	Windows provides several secret ways to exit the Explorer shell. They can be useful when you make registry changes that affect Explorer or for shell developers when 	testing shell extensions.
*!*	Why you may want to restart Explorer ?
*!*	There are several reasons when you may want to exit the Explorer shell and start it again, such as:
*!*You are trying to uninstall some software with shell extensions....
*!* If you leave Explorer, all shell extensions will be unloaded from the shell and 	will be cleanly deleted by the uninstaller. All files that are locked for use by the Explorer.exe process will be released.
*!*	If you applied some tweak which requires you to log off and log in back,in most cases, it is enough to only restart the shell.

*!* create a vfp project add a config.fpw and compile an exe then run.
*!*This code is equivalent to [run taskmanager and  select "file+execute a new task"...dialog & type explorer+return]

If _vfp.StartMode=0
	On Shutdown Quit
Endi
Set Defa To Addbs(Justpath(Sys(16,1)))

*terminate actual explorer
*wait interval 2s
*re start explorer
Local m.myvar
TEXT to m.myvar noshow
taskKill  /f  /im   explorer.exe
timeout /t 2 >nul
start explorer.exe
ENDTEXT
Set Safe Off
Strtofile(m.myvar,"ybate.bat")

&&shellexecute
Declare Integer ShellExecute In SHELL32.Dll Integer nWinHandle,;
	STRING cOperation,;
	STRING cFileName,;
	STRING cParameters,;
	STRING cDirectory,;
	INTEGER nShowWindow

Local m.result
m.result = ShellExecute(0, "open", "EXPLORER.exe","ybate.bat","",0)
If result<=32
	Messagebox("Fail to run!",16+4096,'',1200)
Endi
Quit


the code above is equivalent to this operation.

the code above is equivalent to this operation.

Click on code to select [then copy] -click outside to deselect



*6* created on thursday 02 of november 2017
*!*	this code builds a scrolling form as container with a container class playing as menu.
*!*	this can run 20 applications (window 10 version 1703) where more are win10  modern ones.
*!* the pictures are from web (personal use only) and used as pictureVal option for illustration.
*!* click on image control or label to fire the relative app.
*!* the pictures make some time to load at first start but are speedly placed after the second run (maybe populate the vfp cache ?)
*!*pictures and description are as illustration only (to customize)
*!* internet must be connected to link to some web pictures.
*!*this template can applied as menu to run many other applications.

Close Data All
_Screen.WindowState=1


Create Cursor ycurs (ynum i,img c(140),ytext c(250),xcaption c(50),xcommand c(100))


Local m.x,m.mytext,m.xpict
For i=1 To 20
	Do Case
		Case i=1
			m.x="News,Microsoft.BingNews_8wekyb3d8bbwe!AppexNews"
			m.mytext="1-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_75252e_1-macbook-pro.png"
		Case i=2
			m.x="3D Builder,Microsoft.3DBuilder_8wekyb3d8bbwe!App"
			m.mytext="2-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_902ffb_1-island-12.png"
		Case i=3
			m.x="Calculator,Microsoft.WindowsCalculator_8wekyb3d8bbwe!App"
			m.mytext="3-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_164fbf_03.png"
		Case i=4
			m.x="Calendar,microsoft.windowscommunicationsapps_8wekyb3d8bbwe!microsoft.windowslive.calendar"
			m.mytext="4-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_205545_018.png"
		Case i=5
			m.x="Maps,Microsoft.WindowsMaps_8wekyb3d8bbwe!App"
			m.mytext="5-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_47fd86_20.png"
		Case i=6
			m.x="Cortana,Microsoft.Windows.Cortana_cw5n1h2txyewy!CortanaUI"
			m.mytext="6-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_31d147_6110.png"
		Case i=7
			m.x="Courier,Microsoft.Windowscommunicationsapps_8wekyb3d8bbwe!microsoft.windowslive.mail"
			m.mytext="7-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_1ab1d4_6159.png"
		Case i=8
			m.x="Films et TV,Microsoft.ZuneVideo_8wekyb3d8bbwe!Microsoft.ZuneVideo"
			m.mytext="8-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_392ef7_9806.png"
		Case i=9
			m.x="Finances,Microsoft.BingFinance_8wekyb3d8bbwe!AppexFinance"
			m.mytext="9-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_b4dc54_15254.png"
		Case i=10
			m.x="groove music,Microsoft.ZuneMusic_8wekyb3d8bbwe!Microsoft.ZuneMusic"
			m.mytext="10-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_72f90d_16129.png"
		Case i=11
			m.x="Magnify,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\Magnify.exe"
			m.mytext="11-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_d89c99_17109-dusboy-acrobatiphone.png"
		Case i=12
			m.x="Edge,Microsoft.MicrosoftEdge_8wekyb3d8bbwe!MicrosoftEDge"
			m.mytext="12-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_bf3f69_19312.png"
		Case i=13
			m.x="Mixed Reality Viewer,Microsoft.Microsoft3DViewer_8wekyb3d8bbwe!Microsoft.Microsoft3DViewer"
			m.mytext="13-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_91f094_40763.png"
		Case i=14
			m.x="Meteo,Microsoft.BingWeather_8wekyb3d8bbwe!App"
			m.mytext="14-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_340901_51817.png"
		Case i=15
			m.x="Snippingtool,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\SnippingTool.exe"
			m.mytext="15-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_8d0ee8_51852.png"
		Case i=16
			m.x="PAINT 3D,Microsoft.MSPaint_8wekyb3d8bbwe!Microsoft.MSPaint"
			m.mytext="16-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_91837b_557447-elephant-128.png"
		Case i=17
			m.x="PHOTOS,microsoft.Windows.Photos_8wekyb3d8bbwe!App"
			m.mytext="17-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_f228a9_791572-1325919394-3.jpg"
		Case i=18
			m.x="Sport,Microsoft.BingSports_8wekyb3d8bbwe!AppexSports"
			m.mytext="18-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_0d8ab4_books.png"
		Case i=19
			m.x="Windows Store,Microsoft.WindowsStore_8wekyb3d8bbwe!App"
			m.mytext="19-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_59a913_a-young-leo.png"
		Case i=20
			m.x="XPS viewer,{1AC14E77-02E7-4E5D-B744-2EB1AE5198B7}\xpsrchvw.exe"
			m.mytext="20-Lorem ipsum dolor sit amet, consectetur adipiscing elit. Proin vel risus eget lorem feugiat fermentum nec a turpis. Phasellus purus sem, mollis ac posuere eget, ornare vel orci. Sed ac rutrum nulla."
			m.xpict="http://img.over-blog-kiwi.com/1/43/54/07/20171102/ob_9636e8_navigateur-couleur-icone-5475-96.png"
	Endcase
	Insert Into ycurs Values (i,m.xpict,m.mytext,Getwordnum(m.x,1,','),Getwordnum(m.x,2,',') )
Endfor
Sele ycurs
*brow

Sys(2002)   &&disable cursor (set curs off)
Publi yform
yform=Newobject("ylist")
yform.Show
Read Events
Retu

Define Class ylist As Form
	Left=1
	Top=10
	Width=621
	Height=687
	ShowWindow=2
	BorderStyle=0
	ScrollBars=2
	Caption="Some windows10 modern Apps (20)"
	Name="ylist"

	Procedure Init
		Sele ycurs
		Locate
		With This
			Local m.delta
			m.delta=10
			For i=1 To 20
				.AddObject("ycnt"+Trans(i),"ycnt")
				Sele ycurs
				Go i
				With Eval(".ycnt"+Trans(i))
					.image1.PictureVal=yrequest(Allt(img),.image1)
					.label1.Caption=Trans(ynum)+Spac(2)+xcaption
					.edit1.Value=ytext
					.Left=10
					.Height=97
					.Top=(i-1)*.Height+m.delta
					.Visible=.T.
				Endwith
			Endfor
		Endwith
	Endproc

	Procedure Load
		&&shellexecute
		Declare Integer ShellExecute In SHELL32.Dll Integer nWinHandle,;
			STRING cOperation,;
			STRING cFileName,;
			STRING cParameters,;
			STRING cDirectory,;
			INTEGER nShowWindow
	Endproc
	
	Procedure Destroy
		Clea Events
	Endproc
Enddefine
*EndDefine ylist

Define Class ycnt As Container
	Top = 12
	Left =10
	Height = 97
	Width=600
	BackStyle = 1
	BackColor=0
	BorderWidth = 0
	Name = "ycnt"

	Add Object image1 As Image With ;
		PictureVal = "", ;
		Stretch = 2, ;
		BackStyle = 0, ;
		Height = 90, ;
		Left = 8, ;
		MousePointer = 15, ;
		Top = 5, ;
		Width = 90, ;
		Name = "Image1"


	Add Object edit1 As EditBox With ;
		FontBold = .T., ;
		FontSize = 10, ;
		BackStyle = 0, ;
		BorderStyle = 0, ;
		Height = 72, ;
		Left = 160, ;
		ScrollBars = 0, ;
		Top = 12+27, ;
		Width = 450, ;
		forecolor=Rgb(255,255,255),;
		enableHyperlinkd=.F.,;
		disabledbackcolor=0,;
		specialEffect=2,;
		enabled=.F.,;
		Name = "Edit1"

	Add Object label1 As Label With ;
		AutoSize = .T., ;
		FontBold = .T., ;
		FontSize = 14, ;
		Caption = "1", ;
		Height = 25, ;
		Left = 160, ;
		MousePointer = 15, ;
		Top = 1, ;
		Width = 450, ;
		backstyle=0,;
		ForeColor = Rgb(255,0,0), ;
		SpecialEffect=2,;
		Name = "Label1"

	Procedure image1.Click
		Sele ycurs
		Locate For Allt(Lower(img))==Lower(This.tooltiptext)
		If Found()
			Thisform.WindowState=1
			yrun(Allt(xcommand))
		Endi
	Endproc

	Procedure label1.Click
		This.Parent.image1.Click
	Endproc

	Procedure image1.MouseEnter
		Lparameters nButton, nShift, nXCoord, nYCoord
		This.BorderStyle=1
		This.BorderColor=Rgb(255,255,255)
    this.parent.label1.mouseEnter(1)    
	Endproc

	Procedure image1.MouseLeave
		Lparameters nButton, nShift, nXCoord, nYCoord
		This.BorderStyle=0
    this.parent.label1.mouseLeave(1)
	Endproc

	Procedure label1.MouseEnter
		Lparameters nButton, nShift, nXCoord, nYCoord
		With This
			.ForeColor=Rgb(255,255,0)
			.Left=.Left-2
			.Top=.Top-2
      .parent.image1.mouseEnter(1)
		Endwith
	Endproc

	Procedure label1.MouseLeave
		Lparameters nButton, nShift, nXCoord, nYCoord
		With This
			.ForeColor=255
			.Left=.Left+2
			.Top=.Top+2
      .parent.image1.mouseLeave(1)
		Endwith
	Endproc

Enddefine
*-- EndDefine:ycnt

Function yrun()
	Lparameters xco
	xco=Allt(xco)
	*messagebox(xco)
	Try
		Local m.result
		m.result = ShellExecute(0, "open", "explorer.exe ","shell:Appsfolder\"+m.xco,"",1)
		If result<=32
			Messagebox("Fail to run!",16+4096,'',1200)
		Endi
	Catch
		Messagebox("An error was occured!",16+4096,"Error",1200)
	Endtry
Endfunc

Function yrequest()
	Lparameters lcUrl,ximg
	Local loRequest,xreturn
	m.loRequest = Createobject('MsXml2.XmlHttp')
	m.loRequest.Open("GET",lcUrl,.F.)
	m.loRequest.Send()
	m.xreturn=m.loRequest.ResponseBody
	ximg.tooltiptext=lcUrl   && used only to locate record in cursor -make sure url is unique here.
	m.loRequest=Null
	Return m.xreturn
Endfunc



Digging in windows10 mine
Digging in windows10 mine
Digging in windows10 mine
Digging in windows10 mine

Important:All Codes above are tested on VFP9SP2 & windows 10 pro 64 bits version 1703 ( creator update).

To be informed of the latest articles, subscribe:
Comment on this post